Tag Archives: bandwidth limit

Queue Tree Mikrotik to limit total bandwidth

scripts, , , ,

Hi Guys,
today i’ll show you how to manage the Mikrotik Queue Tree to limit the total bandwidth (for. example you can split a 20Mbps DSL to 4Mbps per 5 users)
In my example i’ll limit upload+download=20Mbps

First of all we need to mark the packets to be traced in the queue:

/ip firewall mangle
add action=mark-packet chain=prerouting in-interface=ether3 new-packet-mark=upload
add action=mark-packet chain=postrouting new-packet-mark=download out-interface=ether3

Then we’ll set up the queue tree:

/queue tree
add max-limit=20M name=total-traffic parent=global queue=default
add name=upload packet-mark=upload parent=total-traffic queue=default
add name=download packet-mark=download parent=total-traffic queue=default

In this case the upload and download mark will be added and when this sum reach the limit it is possibile to send an email as alert (You can find the script for checking the queue tree limit here.)

Enjoy!

Adding automatic rate limits to user-manager accounts.

scripts, , , , , , , , ,

This has been mentioned and posted in a couple of places now however I’d like to post a copy here also in the event that anyone else has further suggestions on improvements for the script, or any further questions.

Although I don’t use it much myself, many Mikrotik users would be familiar with the “user-manager” package built by mikrotik as an “all-in-one” hotspot solution for small-medium installs.

Many of the functions in this are automated, however not the addition of per-account rate limits, which would normally be based on the package purchased. Instead most sites opt to use a preset speed value on a per router basis. An alternative option to this would be to put different users in different IP pools and setup a rate-limited queue tree based on that.

I was requested to build a script for use on the main user-manager mikrotik, that would allow accounts to be assigned a rate limit based on the package someone had purchased. Once set, this speed value remains the same.

Although this is sounds like quite a simple task, there’s a lot of work saved in having something like this automated, leaving you to get back to running day to day tasks rather than having to either limit all users to the same speed or worse, keep one eye on your user list to catch any newly created accounts!

With that I mind I wrote the following basic script to allow newly created accounts to be assigned a rate-limit based on the package they purchased.

You can modify the values to match your own options and rework this to your liking.

In this example you can see that, if I user purchased a $30 package (credit-price=30000) they would be assigned a rate limit of 512k/128k, whereas a $90 purchase would get a 2M/128k limit.

#Script to add rate limit's to newly created user-manager accounts.
#Written by Andrew Cox | Omega-00 | http://www.mikrotik-routeros.com

:local counter
:local check

#Loop through all users in user-manager
:foreach counter in=[/tool user-manager user find] do={

#Check to see if comment contains "RLA" (short for 'rate limit added'). If it doesn't, this account hasn't had a rate limit set yet.
#We only check the first 3 characters, this means you can continue to use the comment field for whatever you like so long as you leave the 'RLA' untouched (if present)
:set check [:pick [/tool user-manager user get $counter value=comment] 0 3]
:if ($check="RLA") do={

#Has RLA, rate limit is already set so ignore

} else={

#Doesn't have RLA Set rate-limit based on initial purchase pricing
:if ([/tool user-manager user get $counter credit-price] ="30000") do={/tool user-manager user set $counter rate-limit="512k/128k" comment="RLA"}
:if ([/tool user-manager user get $counter credit-price] ="60000") do={/tool user-manager user set $counter rate-limit="1M/128k" comment="RLA"}
:if ([/tool user-manager user get $counter credit-price] ="90000") do={/tool user-manager user set $counter rate-limit="2M/128k" comment="RLA"}
}  }

Simple RouterOS http load/bandwidth tester

Uncategorized, , , , , , , , , , , ,

Disclaimer: I am not responsible for what you choose to do with this script and/or what damage you incur. It uses features of RouterOS in ways I have to assume they were not intended so user beware.

I wrote a little script today that allows very simple load/bandwidth testing.

Some suggested uses:
– basic testing of apache http servers on a VPS
– bandwidth testing when you’re not onsite and don’t have a remote mikrotik with enough bandwidth test to.

I recommend you don’t exceed 500 iterations on an RB1000 however if you’re using it for a bandwidth test then you should only need 4 threads or so.

If you do exceed this number, or manage to crash the console anyway,  login via winbox and run the clear script a couple of times to remove the created scheduler entries.

Server is the server you wish to connect and
File is the file you wish to download (this is not saved).
Time is how long you want to run the test for (so you can see the average bandwidth or monitor the server you’re checking against).

For example: http://www.example.tld

Server would be www.example.tld

File would be index.php or index.html or index.asp etc etc

For a bandwidth test you’d do better to look around for a reasonably sized file you can download (a linux iso on an ISP mirror would work).

#HTTP testing implementation v3
#Written By Omega-00 - December 2010

#user editable values
:local server "server.tld"
:local file "index.php"
#Recommend not running any more than 500 for RB1000/1100/800
:local iterations 500
#amount of time to run script for in seconds
:local time 60

### End of user editable values ###
:local counter

:for counter from=1 to=$iterations do={
/system scheduler add interval=1s start-time=startup name="load-test-$counter" on-event="/tool fetch keep-result=no mode=http address=$server host=$server src-path=\"$file\"; /tool fetch keep-result=no mode=http address=$server host=$server src-path=\"$file\";"
}

#wait $time seconds for threads to run
:delay $time
:foreach counter in=[/system scheduler find] do={
:if ([:find [/system scheduler get $counter name] "load-test-"] !="") do={/system scheduler remove $counter}
}

And a cleanup script in case you crash the console from setting the iterations value too high.

#Script for clearing entries in the event of script crash 

:foreach counter in=[/system scheduler find] do={
:if ([:find [/system scheduler get $counter name] "load-test-"] !="") do={/system scheduler remove $counter}
}

If there’s interest in this I might make another version of the script that can spider through a website and load multiple pages at once (increasing the effectiveness of using this as a server load tester and avoiding caching from the host machine).

Update: Version 4 of the script (uses :execute command instead of scheduler to run parallel processes)

#HTTP testing implementation v4
#Written By Omega-00 - Jan 2011

#user editable values

#Recommend not running any more than 500 for RB1000/1100/800
:local iterations 500

:local runcmd "/tool fetch keep-result=no url=\"http://example.tld/index.php\""
:local time "60"

### End of user editable values ###
:local counter
:local counter2

:log info "Run Command: $runcmd"

:for counter2 from=1 to=$time do={
:for counter from=1 to=$iterations do={
:execute $runcmd
}
:delay 1
}